stats/512-mb.plot at master · curl/stats · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
# SVG output
set terminal svg size 1920,1080 dynamic font ",24"

# title
set title "512MB download alloc spend" font ",48"
# where's the legend
set key bottom right

# Identify the axes
#set xlabel "Time"
set ylabel "Total amount of allocations in bytes" tc "#0060ad"

set style line 1 \
    linecolor rgb '#0060ad' \
    linewidth 4

set style line 2 \
    linecolor rgb '#40c040' \
    linewidth 4

set grid
unset border

# time formated using this format
set timefmt "%Y-%m-%d"
set xdata time

set yrange [0:]
set y2range [0:]

set xtics rotate 3600*24*365.25 nomirror
unset mxtics
set ytics nomirror

set y2label "Number of allocations" tc "#40c040"
set y2tics
set ytics nomirror

load "stats/logo.include"

# set the format of the dates on the x axis
set format x "%Y"
set format y "%.0s%c"
set datafile separator ";"
plot ARG1.'/512-mb.csv' using 2:4 with lines linestyle 1 title "Total amount of memory used", \
 ARG1.'/512-mb.csv' using 2:3 axis x1y2 with lines linestyle 2 title "Number of allocations"